$ cat error-4402-en-genero-subindices-sql.md

Genero BDL

Error -4402 en Genero: subíndices en SQL estático

16 Nov 2026 · 3 min de lectura

El problema: error -4402 en Genero al compilar

El error -4402 en Genero aparece cuando quieres filtrar por un carácter concreto de una variable y lo escribes directamente en el SELECT:

MAIN
  DEFINE l_codigo CHAR(10)
  DEFINE l_total INTEGER

  LET l_codigo = "ABC1234567"
  SELECT COUNT(*) INTO l_total FROM pedidos
   WHERE tipo = l_codigo[3,3]
  DISPLAY l_total
END MAIN

fglcomp no lo compila:

falla.4gl:7:17:7:29:error:(-4402) In this type of statement, subscripting may be applied only to array variables to select individual array elements.

El mensaje confunde: habla de arrays, y l_codigo no es un array, es una cadena. Lo que dice en realidad es que, dentro de esta sentencia, los corchetes solo se admiten para el índice de un array, no para extraer una subcadena.

La causa

El manual lo explica en la guía de migración desde Informix 4GL (Using variable subscripts in SQL): en el SQL estático de Genero no se admite aplicar subíndices a las variables del programa.

El motivo viene de Informix 4GL, que sí aceptaba esa sintaxis, pero, según el manual, ignoraba el [3,3] sin avisar y usaba la variable entera. El SELECT anterior, en Informix 4GL, buscaba tipo = "ABC1234567", no tipo = "C". Genero lo rechaza al compilar para no repetir ese error.

Por eso suele aparecer al compilar código heredado: si un programa antiguo tenía un subíndice en un WHERE, nunca filtró por lo que parecía.

La solución

Asigna la subcadena a una variable antes de la sentencia:

MAIN
  DEFINE l_codigo CHAR(10)
  DEFINE l_tipo CHAR(1)
  DEFINE l_total INTEGER

  LET l_codigo = "ABC1234567"
  LET l_tipo = l_codigo[3,3]
  SELECT COUNT(*) INTO l_total FROM pedidos
   WHERE tipo = l_tipo
  DISPLAY l_total
END MAIN

Fuera del SQL, l_codigo[3,3] es una expresión normal de Genero y funciona sin problemas.

Lo que sí se puede hacer

El subíndice sobre una columna de la tabla sí compila, porque no lo procesa Genero sino la base de datos:

MAIN
  DEFINE l_tipo CHAR(4)
  DEFINE l_total INTEGER

  LET l_tipo = "EXPO"
  SELECT COUNT(*) INTO l_total FROM pedidos
   WHERE tipo_envio[1,4] = l_tipo
  DISPLAY l_total
END MAIN

Con -W all, fglcomp lo marca con un aviso, no con un error:

columna.4gl:7:10:7:24:warning:(-8059) SQL statement or language instruction with vendor proprietary SQL syntax.

Es la sintaxis de subcadena de columnas de Informix: funciona en Informix, pero en otra base de datos depende de si esta la admite.

Conclusión

-4402 en un SELECT no tiene nada que ver con arrays: es un subíndice sobre una variable dentro de SQL estático. Se arregla con una variable intermedia. Si el código viene de Informix 4GL, conviene revisar qué hacía antes ese WHERE, porque es probable que no filtrara lo que parecía.

Fuentes

  • Manual Genero BDL 6.00: Using variable subscripts in SQL (migración desde Informix 4GL) y la tabla de errores (-4402).

Temas:

0 comentarios

Deja una respuesta

Tu dirección de correo electrónico no será publicada. Los campos obligatorios están marcados con *